Help me improve the abc music notation

[winter-loo]

This is my first time to write abc music notation in ohm grammar. Help me review the grammar.

Abc {
  File = eol* (FileHeaders eol eol+)? TuneBook

  FileHeaders = FileHeader (eol FileHeader)*
  FileHeader
    = reservedFileHeaderField
    | UnknownFileHeaderField --unknown

  TuneBook = Tune (eol eol+ Tune)* eol*

  Tune = TuneHeader (eol TuneBody)?
  TuneHeader = TuneHeaderStartField (eol TuneHeaderMiddleField)* eol TuneHeaderEndField
  TuneHeaderMiddleField
    = reservedTuneHeaderField
    | UnknownTuneHeaderField --unknown

  TuneBody
    = (InBodyInfoFieldList eol)? TuneBodyPart (~(eol InBodyInfoFieldList) eol? TuneBodyPart)* (eol InBodyInfoFieldList)?

  TuneBodyPart
    = TuneBodyPart eol InBodyInfoFieldList eol TuneBodyPart --middle
    | InlineInfoFieldList --inline
    | MusicCode
    | reservedLetter --reserved

  MusicCode = MusicCodePart+

  // rule in front has higher priority
  MusicCodePart
    = NoteSeq+ --noteseq
    | rest
    | "(" --slurStart
    | ")" --slurEnd
    | bar

  rest =
      | ("z" | "x") noteLen? --inside
      | ("Z" | "X") number? --cross

  bar = ":|2" | "||" | "[|" | "|]" | "|:" | ":|" | "[1" | "[2" | "::" | "|1" | "|"

  NoteSeq
    = noteConstruct binaryOps noteConstruct --binary
    | NoteGroup brokenOp --dotted
    | PairingAnnotatedNote --pairedAnnotation
    | NoteGroup --group
    | noteConstruct

  binaryOps = binaryOp+
  binaryOp
    = brokenOp --broken
    | tieOp --tie
  brokenOp = ">"+ | "<"+
  tieOp = "-"

  baseNoteGroup
    = "[" annotatedNote+ "]" --chord
    | "(" #(digit) annotatedNote+ --nplet
    | annotatedNote binaryOp annotatedNote --binary
    | annotatedNote+

  NoteGroup = chordAnnotation? baseNoteGroup

  noteConstruct = (graceNote spaces)? chordedNote
  graceNote = "{" spaces baseNote+ spaces "}"
  chordedNote = (chordAnnotation spaces)? annotatedNote

  // slur symbols could exist before and after baseNote
  annotatedNote = (annotationOp spaces)? "("? baseNote ")"?
  annotationOp =
    | annotationOp annotationOp --concat
    | annotationOp space+ annotationOp --gap
    | annotation

  chordAnnotation = "\"" chordAnnoText "\""
  // <note><accidental><type></bass>
  chordAnnoText = "A".."G" #(chordAnnoSharp)? #(chordAnnoType)? #("/" ("A".."G" | "a".."g"))?
  chordAnnoSharp = "b" | "#" | "\u266d" | "\u266e" | "\u266f"
  chordAnnoType =
    | chordAnnoType chordAnnoType --many
    | "m" | "min" | "maj" | "dim" | "aug" | "+" | "sus" | number

  PairingAnnotatedNote
    = chordAnnotation? "!trill(!" PairingMiddle "!trill)!" baseNote
    | chordAnnotation? "!crescendo(!" PairingMiddle "!crescendo)!" baseNote
    | chordAnnotation? "!<(!" PairingMiddle "!<)!" baseNote
    | chordAnnotation? "!diminuendo(!" PairingMiddle "!diminuendo)!" baseNote
    | chordAnnotation? "!>(!" PairingMiddle "!>)!" baseNote
  PairingMiddle = baseNote NoteSeq* chordAnnotation?

  baseNote = accidental? noteName octave? noteLen?

  // decorations may be applied to notes, rests, note groups, and bar lines
  annotation =
    | "\"" annoText "\"" --anno
    | decoration --deco
  annoText = (~(eol | "\"") any)*

  decoration =
    | "."
    | "~"
    | "H"
    | "L"
    | "M"
    | "O"
    | "P"
    | "S"
    | "T"
    | "u"
    | "v"
    | "!trill!"
    | "!lowermordent!"
    | "!uppermordent!"
    | "!mordent!"
    | "!pralltriller!"
    | "!roll!"
    | "!turn!"
    | "!turnx!"
    | "!invertedturn!"
    | "!invertedturnx!"
    | "!arpeggio!"
    | "!>!"
    | "!accent!"
    | "!emphasis!"
    | "!fermata!"
    | "!invertedfermata!"
    | "!tenuto!"
    | "!0!"
    | "!1!"
    | "!2!"
    | "!3!"
    | "!4!"
    | "!5!"
    | "!+!"
    | "!plus!"
    | "!snap!"
    | "!slide!"
    | "!wedge!"
    | "!upbow!"
    | "!downbow!"
    | "!open!"
    | "!thumb!"
    | "!breath!"
    | "!pppp!"
    | "!ppp!"
    | "!pp!"
    | "!p!"
    | "!mp!"
    | "!mf!"
    | "!f!"
    | "!ff!"
    | "!fff!"
    | "!ffff!"
    | "!sfz!"
    | "!segno!"
    | "!coda!"
    | "!D.S.!"
    | "!D.C.!"
    | "!dacoda!"
    | "!dacapo!"
    | "!fine!"
    | "!shortphrase!"
    | "!mediumphrase!"
    | "!longphrase!"

  accidental = "^"+ | "_"+ | "="
  noteName = "A".."G" | "a".."g"
  octave = ","+ | "'"+
  noteLen =
    | number "/" number --fra
    | "/" number        --div
    | "/"+              --half
    | number            --mul

  InlineInfoFieldList = InlineInfoField+
  InlineInfoField = "[" InlineInfoFieldX "]"
  InlineInfoFieldX =
    | reservedInlineField
    | UnknownField --unknown
  inlineFieldValue = (~(eol | "]" | "[") any)*
  InBodyInfoFieldList = InBodyInfoField (eol InBodyInfoField)*
  InBodyInfoField =
    | reservedInBodyField
    | UnknownField --unknown

  TuneHeaderStartField = "X:" number
  TuneHeaderEndField   = "K:" oneLineValue

  reservedFileHeaderField
    = reservedHeaderOnlyField
    | reservedCommonField<oneLineValue>

  reservedTuneHeaderField =
    | reservedTuneHeaderFieldX
    | reservedHeaderOnlyField
    | reservedCommonField<oneLineValue>

  reservedTuneHeaderFieldX =
    | "P:" spaces oneLineValue
    | "Q:" spaces qKeyedValue
    | "T:" spaces oneLineValue
    | "V:" spaces oneLineValue
    | "W:" spaces oneLineValue

  reservedInBodyField =
    | reservedInBodyFieldX
    | reservedCommonField<oneLineValue>

  reservedInBodyFieldX =
  	| "K:" spaces oneLineValue --key
    | "P:" spaces oneLineValue --part
    | "Q:" spaces qKeyedValue --tempo
    | "s:" spaces oneLineValue --symbolLine
    | "T:" spaces oneLineValue --tuneTitle
    | "V:" spaces oneLineValue --voice
    | "W:" spaces oneLineValue --wordsAfter
    | "w:" spaces oneLineValue --wordsParallel

  reservedInlineField =
    | reservedInlineFieldX
    | reservedCommonField<inlineFieldValue>

  reservedInlineFieldX =
   	| "K:" spaces inlineFieldValue --key
    | "P:" spaces inlineFieldValue --part
    | "Q:" spaces qKeyedValue --tempo
    | "R:" spaces inlineFieldValue --rhythm
    | "V:" spaces inlineFieldValue --voice

  reservedHeaderOnlyField =
    | "A:" spaces oneLineValue
    | "B:" spaces oneLineValue
    | "C:" spaces oneLineValue
    | "D:" spaces oneLineValue
    | "F:" spaces oneLineValue
    | "G:" spaces oneLineValue
    | "H:" spaces oneLineValue
    | "S:" spaces oneLineValue
    | "Z:" spaces manyLineValue
    | "O:" spaces oneLineValue

  reservedCommonField<value> =
    | "I:" "linebreak" space+ linebreakMarks --instruction
    | "L:" spaces noteLen --unitNoteLength
    | "M:" spaces noteLen --meter
    | "m:" spaces value --macro
    | "N:" spaces value --notes
    | "R:" spaces value --rhythm
    | "r:" spaces value --remark
    | "U:" spaces value --userDefined
    | fieldContinue spaces value --fieldContinue

  qKeyedValue = dqTextString? spaces  (number "/" number spaces "=")? spaces number spaces dqTextString?

  linebreakMarks = linebreakMark (space+ linebreakMark)*
  linebreakMark
    = "$"
    | "!"
    | "<EOL>"
    | "<none>"

  UnknownFileHeaderField = ~(reservedFileHeaderField) key oneLineValue
  UnknownTuneHeaderField = ~(reservedTuneHeaderField | TuneHeaderStartField | TuneHeaderEndField) key oneLineValue
  UnknownField = ~(reservedInBodyField | reservedInlineField | reservedTuneHeaderField | reservedFileHeaderField) key (oneLineValue | inlineFieldValue)

  key = letter ":"
  textString  = (~(eol | "\"") any)*
  dqTextString = "\"" textString "\""
  // allow newline in value but line beginning with letter + colon
  // is a marker for info field
  oneLineValue  = (~(eol | "%") any)*
  manyLineValue = (~(eol key) any)*
  comment = "%" (~eol any)*
  commentLine = comment eol
  eol
    = eol commentLine --lineComment
    | "\\" spaces eol --lineContinue
    | "\r\n" | "\n" | "\r"
  space := " " | "\t" | comment
  number = digit+
  fieldContinue = "+:"
  reservedLetter =
    | "!" | "\"" | "#" | "$" | "%" | "&" | "*" | "+"
    | "-" | "." | "/" | ":" | ";" | "<" | "=" | ">" | "?" | "@"
    | "`" | "~"
    | "0".."9" | "A".."Z" | "a".."z"
}